home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
The X-Philes (2nd Revision)
/
The X-Philes Number 1 (1995).iso
/
xphiles
/
hp48_1
/
hp16c
< prev
next >
Wrap
Text File
|
1995-03-31
|
2KB
|
143 lines
DIR
LJ
\<< DUP
IF TOREAL
THEN TOBIN
DO RL DUP
UNTIL # 1h AND TOREAL
END RR
ELSE # 0h
END
\>>
MSKL
\<< TRIMN \-> n
\<< # 0h 1 n
START RR # 1h RR OR
NEXT
\>>
\>>
MSKR
\<< TRIMN \-> n
\<< # 0h 1 n
START SL # 1h OR
NEXT
\>>
\>>
RLn
\<< \-> X n
\<< X TOBIN 1 n TRIMN
START RL
NEXT
\>>
\>>
RRn
\<< \-> X n
\<< X TOBIN 1 n TRIMN
START RR
NEXT
\>>
\>>
RLC
\<< TOBIN RL SWAPC
\>>
RRC
\<< TOBIN SWAPC RR
\>>
RLCn
\<< \-> X n
\<< X TOBIN 1 n TRIMN
START RLC
NEXT
\>>
\>>
RRCn
\<< \-> X n
\<< X TOBIN 1 n TRIMN
START RRC
NEXT
\>>
\>>
CNTB
\<< 0 SWAP TOBIN 1 RCWS
START
IF DUP # 1h AND TOREAL
THEN SWAP 1 + SWAP
END RR
NEXT DROP
\>>
SB
\<< # 1h SWAP RLn OR
\>>
CB
\<< # 1h NOT SWAP RLn AND
\>>
TB
\<< RRn # 1h AND
\>>
TOBIN
\<< \->NUM \-> X
\<<
IF X TYPE 10 \=/
THEN X RE R\->B
ELSE X
END
\>>
\>>
TOREAL
\<< \->NUM \-> X
\<<
IF X TYPE 10 ==
THEN X B\->R
ELSE X
END
\>>
\>>
TRIMN
\<< TOREAL ABS RCWS MOD
\>>
SWAPC
\<< DUP CARRY SWAP # 1h AND 'CARRY' STO SWAP # 1h NOT AND OR
\>>
CARRY # 0h
CST { ON16 BASE
{ "R\->SB" { R\->SB SB\->R } }
RLn RRn RLC RRC RLCn RRCn CNTB SB CB TB
}
R\->SB
\<<
IF DUP 0 <
THEN NEG R\->B NEG
ELSE R\->B
END
\>>
SB\->R
\<<
IF DUP 2 RCWS 1 - ^ R\->B AND B\->R
THEN NEG B\->R NEG
ELSE B\->R
END
\>>
ON16
\<< -62 SF -63 SF CST 1 { OFF16 } REPL DUP 'CST' STO MENU
\>>
OFF16
\<< -62 CF -63 CF CST 1 { ON16 } REPL DUP 'CST' STO MENU
\>>
BASE
\<< 9 MENU
\>>
\GaENTER
\<< \-> X
\<< X 1 1 SUB NUM \-> Y
\<<
IF Y 48 \>= Y 57 \<= AND
THEN "#" X +
ELSE X
END
\>>
\>> OBJ\->
\>>
END